*
      * un champs de type BLOB_FILE contient non pas une image
      *  mais le chemin d'une image
      *  a/ à lire lors d'un insert ou d'un update
      *  a/ à écrire lors d'un select
      *
      *
      * SEU (janvier 2000) refuse le mot-clé SQLTYPE
      *     ==> forcez, ca passe trés bien à la compil.
      *
     d image           s                   SQLTYPE(BLOB_FILE)
     d articles      e ds
     C/exec sql
     C+ DECLARE C1 CURSOR FOR SELECT noart FROM articles FOR UPDATE
     C+ OF image
     C/end-exec
     C/exec sql
     C+         open c1
     C/end-exec
     c                   dou       sqlcod <> 0
     C/exec sql
     C+         fetch c1 into :noart
     C/end-exec
     c                   if        sqlcod <> 0
     c                   leave
     c                   endif
     c                   eval      image_fo = SQFRD
     c                   eval      image_name = '/html/TOOLS/GIF/' +
     c                              %trimr(noart) + '.gif'
     c                   eval      image_nl = %len(%trim(image_name))
     C/exec sql
     C+         update articles set image = :image
     C+          where current of c1
     C/end-exec
     c                   enddo
 
     C/exec sql
     C+         close c1
     C/end-exec
     C/exec sql
     C+         commit
     C/end-exec
     c                   eval      *inlr = *on